Programming in D for Python Programmers

From D Wiki
Revision as of 10:25, 25 March 2023 by Porton (talk | contribs) (broken links corrected)
(diff) ← Older revision | Latest revision (diff) | Newer revision → (diff)
Jump to: navigation, search

51o29P-BnzL.jpg

(Non-accredicted) Masters D degree: D, the Best Programming Language, for Former Python Developers
Victor Porton
19 May 2021

"High Master" diploma of D development. No prerequisites (except of Python knowledge).

D programming language or DLang for Python programmers: rapid software development of high performance software and a reliable software technology. “There is no best programming language”, they say. There is, for most applications it is D. The course starts from a comparison of D to Python. Then it explains D starting from simple features (types, variables, functions, expressions, statements) up to advanced ones (object oriented programming, templates, mixins, contract programming, overloading of operators, etc.)

Currently we have only text lectures and exams, but addition of video lectures is planned.

"Often, programming teams will resort to a hybrid approach, where they will mix Python and C++, trying to get the productivity of Python and the performance of C++. The frequency of this approach indicates that there is a large unmet need in the programming language department.

D intends to fill that need. It combines the ability to do low-level manipulation of the machine with the latest technologies in building reliable, maintainable, portable, high-level code. D has moved well ahead of any other language in its abilities to support and integrate multiple paradigms like imperative, OOP, and generic programming"

-- Walter Bright


This section is under development - feel free to suggest improvements or additions.


D is Like Native Python

  • D for the Win A former Python programmer explores the benefits from moving to D
  • A hedge fund quant finds that Python begins to choke on the data volumes requiring processing, but that D can cope and is productive.


AdRoll is known for their use of Python elsewhere, but their data scientists use D. According to Andrew Pascoe, senior data scientist at AdRoll, "One of the clearest advantages of using D compared to other typical data science workflows is that it compiles down into machine code. Without an interpreter or virtual machine layer, we can rip through data significantly faster than other tools like a Java hadoop framework, R, or python would allow. But D’s compiler is fast enough that in many cases it can be run as if it were a scripting language....The key thing here that separates D from other efficient languages like the oft-suggested C or C++ is that D frees you to program in the style you feel most comfortable with at the given time". He says that they have found that they "can rapidly prototype new infrastructure and analysis tasks, and when efficiency becomes a core concern, we have the ability to refactor that same code base to squeeze as much performance out as possible".


IPython Notebook / Jupyter

An early-stage extension to Python exists to allow writing D extensions inline within an ipython/Jupyter notebook


Generators and List Comprehensions

Python's generators and list comprehensions have been thought to be two of the most difficult concepts to replicate in other languages. For the D solution to the problem solved by Python generators, see D Ranges and lazy evaluation. For list comprehensions, see UFCS.


Parallel Programming

Parallel programming has become increasingly in focus as we approach the beginning of the end of the free lunch from Moore's Law. D makes multiprocessing and threading as simple as possible, but not simpler:

Simple example from std.parallelism documentation 

import std.algorithm, std.parallelism, std.range;

void main() {
    // Parallel reduce can be combined with
    // std.algorithm.map to interesting effect.
    // The following example (thanks to Russel Winder)
    // calculates pi by quadrature  using
    // std.algorithm.map and TaskPool.reduce.
    // getTerm is evaluated in parallel as needed by
    // TaskPool.reduce.
    //
    // Timings on an Athlon 64 X2 dual core machine:
    //
    // TaskPool.reduce:       12.170 s
    // std.algorithm.reduce:  24.065 s

    immutable n = 1_000_000_000;
    immutable delta = 1.0 / n;

    real getTerm(int i)
    {
        immutable x = ( i - 0.5 ) * delta;
        return delta / ( 1.0 + x * x ) ;
    }

    immutable pi = 4.0 * taskPool.reduce!"a + b"(
        std.algorithm.map!getTerm(iota(n))
    );
}

Interfacing D with an existing codebase

D calling embedded Python 

 
void main() {
    auto context = new InterpContext();
    context.a = 2;
    context.py_stmts("print ('1 + %s' % a)");
}

Lua D example 

import luad.all;

void main()
{
    auto lua = new LuaState;
    lua.openLibs();

    auto print = lua.get!LuaFunction("print");
    print("hello, world!");
}

Web development, concurrency and JSON/BSON/XML

Phobos includes bindings to the widely-used external curl library within Phobos (std.net.curl) and does include provision within std.csv, std.json and std.xml for processing structured data. The JSON and XML implementations in Phobos could be better, and many people choose to use an external library. The most popular solution for this is Vibe D, and this comes with a useful framework for web development, networking, fiber-based concurrency, JSON and BSON. One can write fiber-oriented code without having to deal with callbacks. (See CyberShadow's presentation at Dconf 2013 for an excellent review of the differences).

Atila Neaves has done one benchmark study on Vibed vs Go vc C vs Erlang in a MQTT broker implementation

Officially vibed is in beta, but the author seems to have high standards, and for many purposes you may find that this is good enough to be production-ready. (Of course, caveat emptor, it goes without saying).

Other general solutions include those available in Adam Ruppe's ARSD micro-framework, and CyberShadow's AE library. See the forums for some further possibilities on the JSON and XML front. D's slices facilitate fast and efficient parsing, and as of some time back, the XML parser in the Tango library was possibly the fastest in the world.

Simple HTTP server 

import vibe.d;

shared static this()
{
	auto settings = new HTTPServerSettings;
	settings.port = 8080;

	listenHTTP(settings, &handleRequest);
}

void handleRequest(HTTPServerRequest req,
                   HTTPServerResponse res)
{
	if (req.path == "/")
		res.writeBody("Hello, World!", "text/plain");
}

Declaring a REST interface 

interface IExampleAPI
{
    // Matches "GET /"
    string getIndex();
    // Matches "GET /data"
    @property string data();
    // Matches "PUT /data"
    @property void data(string info);
    // Matches "POST /sum"
    // or "GET /sum?a=...&b=..."
    int postSum(int a, int b);
    // Matches "GET /item/<category>/<item>"
    @path("item/:category/:item")
    int getItem(string _category, int _item);
}


REST Client 

class Example : IExampleAPI
{
    override:
        string getIndex() { return "Index!"; }
        string _data;
        @property string data() { return _data; }
        @property void data(string v) { _data=v; }
        int postSum(int a, int b) {
            return a + b;
        }
       int getItem(string _category,string _item) {
           // ...
      }
}

void main(string[] args)
{
    auto api = new RestInterfaceClient!IExampleAPI("http://localhost/");
    auto index = api.getIndex();
    api.data ="My data";
    assert(api.data =="My data");
    assert(api.postSum(2, 3) == 5);
}

REST Server 

class Example : IExampleAPI
{
    override:
        string getIndex() { return "Index!"; }
        string _data;
        @property string data() { return _data; }
        @property void data(string v) { _data=v; }
        int postSum(int a, int b) {
           return a + b;
       }
      int getItem(string _category,string _item) {
          // ...
       }
}

shared static this() // vibed replacement for main
{
    auto routes = new URLRouter;
    registerRestInterface!IExampleAPI(routes, new Example(), "/");
    auto settings = new HTTPServerSettings;
    settings.port = 8080;
    listenHTTP(settings, routes);
}


Email

There is support for sending emails by SMTP in the standard library under std.net.curl.SMTP in vibe.d, arsd and AE Utils.

Vibe.d Send Email Example 

import vibe.core.log;
import vibe.mail.smtp;


void main()
{
	auto settings = new SMTPClientSettings("smtp.example.com", 25);
	settings.connectionType = SMTPConnectionType.startTLS;
	settings.authType = SMTPAuthType.plain;
	settings.username = "username";
	settings.password = "secret";

	auto mail = new Mail;
	mail.headers["From"] = "<user@isp.com>";
	mail.headers["To"] = "<recipient@domain.com>";
	mail.headers["Subject"] = "Testmail";
	mail.bodyText = "Hello, World!";
	
	logInfo("Sending mail...");
	sendMail(settings, mail);
	logInfo("done.");
}

For MIME support see Arsd and AE Utils (under code.dlang.org there are bindings for gmime). No IMAP as yet, but bindings are under development.


Numerical computing


Libraries - what is the D equivalent of pypi and pip

See code.dlang.org and the DUB package manager .


Scripting

Since D provides type inference, high-level constructs, and fast compile-time it is a great language for writing scripts. The first line of the file is ignored if it begins with #! - by combining this with rdmd which handles dependency resolution, D becomes a leader in machine-code scripting language.

Reading comma separated / CSV text - example from std.csv 

auto text = "Name,Occupation,Salary\r"
    "Joe,Carpenter,300000\nFred,Blacksmith,400000\r\n";

foreach(record; csvReader!(string[string])
        (text, null))
{
    writefln("%s works as a %s and earns $%s per year.",
             record["Name"], record["Occupation"],
             record["Salary"]);
}

Generating optimized machine code at compile time for compiled regex pattern matching 

  string phone = "+31 650 903 7158";
  auto phoneReg = ctRegex!r"^\+([1-9][0-9]*) [0-9 ]*$";
  auto m = match(phone, phoneReg);
  assert(m);
  assert(m.captures[0] == "+31 650 903 7158");
  assert(m.captures[1] == "31");

Next Steps

Retrieved from "https://wiki.dlang.org/?title=Programming_in_D_for_Python_Programmers&oldid=10151"