Programming in D for C++ Programmers

Overview

D is a modern multi-paradigm programming language that emphasizes both productivity and native efficiency. D does not compromise performance while making great strides in productivity and program correctness, which makes it a great choice for C++ programmers.

D also emphasizes modeling power: D allows for the design and implementation of high-level interfaces without compromising performance, allowing unparalleled code reuse in performance-sensitive projects.

D can interface natively with both C and C++ code while shedding the burden of backwards compatibility with C source code, which allows it to make the easy way the correct way.

Header Files

D has a comprehensive, no-nonsense module system that alleviates the need for header files. Symbols can be forward-referenced freely.

D still supports the equivalent of header files - D interface files - which can be used to interface with C or C++ code, or closed-source D code.

Compile Times

D is designed to be fast to compile. Despite having more comprehensive and intuitive metaprogramming features than C++, compilation times tend to be significantly shorter for equivalent programs.

The short compilation time also makes D suitable for writing scripts, executed with rdmd:

#!/usr/bin/env rdmd

void main()
{
    writeln("hello, world");
}

$ chmod +x hello.d && ./hello.d
hello, world

Initialization

In D, all variables are initialized by default:

int i;
writeln(i); // 0
double f;
writeln(f); // nan
int* p;
writeln(p); // null

Variables can be left explicitly uninitialized:

int i = void;
// i is not initialized; its value is undetermined

Thus the default is flipped in favor of safe, bug-free code.

Syntactical Improvements

Empty statements using ; are disallowed:

if(cond); // Error: use '{ }' for an empty statement, not a ';'
    statement();

D also disallows dangling else:

Checked memory safety and functional purity

D supports opt-in, transitively-enforced memory safety:

import std.stdio;

void main() @safe // Verified by the compiler to be memory safe
{
    writeln("hello, world");
}

D also supports opt-in functional purity, giving semantic cues to both the programmer and the compiler. Functional purity makes programs easier to reason about for programmers, and easier to optimize for compilers.

Concurrency

D's memory model is designed to make shared memory explicit, greatly reducing the potential for concurrency bugs:

import core.atomic;

// Static variables are TLS by default
int tlsVar = 0;

// Static variables of shared or immutable types are global
shared(int) globalVar = 0;
immutable(int) immutableVar = 42;

void printVars()
{
    import std.stdio;
    writeln(tlsVar, " ", globalVar.atomicLoad(), " ", immutableVar);
}

void main()
{
    import std.concurrency;

    tlsVar = 42;
    globalVar.atomicStore(42);

    printVars(); // Output: 42 42 42
    spawn(&printVars); // Output: 0 42 42
}

std.concurrency presents a message-passing API for threading, and std.parallelism presents an API for easy parallelization.

Immutability

D supports transitive immutable data, enforced by the type system. A variable of immutable type is guaranteed to never change after initialization.

const bridges mutable and immutable data into a common supertype, enabling functions to receive both mutable and immutable data.

Metaprogramming

D templates are both more expressive and easier to read and write than C++ templates. static-if enables conditional branching in imperative style, eliminating the need for specialized dummy types.

Ranges vs Iterators

D espouses ranges, an evolution of the iterator concept more conducive to component programming. The following program reads lines from standard input, puts them in an array, sorts them, and prints them to standard output in order:

import std.stdio;
import std.array;
import std.algorithm;

void main()
{
    stdin
        .byLine(KeepTerminator.yes)
        .map!(a => a.idup)
        .array
        .sort
        .copy(
            stdout.lockingTextWriter());
}

Unicode

D and its standard library were designed with Unicode in mind, and supports Unicode on a number of levels. D source files are UTF encoded, and the types string, wstring and dstring are UTF-8, UTF-16 and UTF-32 strings respectively. std.utf and std.uni are standard library modules presenting various UTF and Unicode algorithms. std.regex is Unicode-aware.