View source for Property Discussion Wrap-up

This is a wrap-up of the property discussion which happened around 25. January 2013. There have been some discussion before and there might be more in the future :-)

Except from off-topic, meta and personal discussions which are not summarized on this page these issues were discussed:

== Link to discussion ==
If you've got too much time, the original discussions can be read here:

* http://forum.dlang.org/thread/ceukykobasewoexsrveb@forum.dlang.org
* http://forum.dlang.org/thread/kdqrnl$13ft$1@digitalmars.com

DIPS:

Current
* http://wiki.dlang.org/DIPs

Superceded
* http://www.prowiki.org/wiki4d/wiki.cgi?LanguageDevel/DIPs

== Property ==

* Everyone agrees that @property doesn't work well right now. People disagree what's the actual problem with @property. Some people were arguing to remove @property completely. It's not clear if those were advertising making normal functions callable like @properties or removing @property without replacement.

=== Why @property ===
As there were suggestions of removing @property completely we should think about what problem @properties should solve:

* Properties are a replacement for fields
** Unlike fields, they are polymorphic
** As they are supposed to be used as fields, they are for data access and nothing else
** They are especially not there to make function calls without parentheses. This is a different issue. To the developer properties are not functions, they're enhanced fields. The fact that they are implemented as functions is a implementation detail.
*** D as a systems programming language should still provide a way to detect if something is a property and to get the getter/setter. This shouldn't be visible in normal usage.
** Replacing a field by a property should be transparent 
* Properties allow executing additional code. Checking the supplied value, firing events,...
** As a property looks like data access, complexity should be kept constant.
* Properties allow making a field readonly (public get, private/no set), readwrite(public get/set) or write-only (private/no get, public set).


An example for property usage:
<syntaxhighlight lang="D">
struct A
{
    int _days;
    @property int weeks()
    {
        return _days/7;
    }

    @property void weeks(int value)
    {
        assert(value <= 42);
        _days = value*7;
    }
}

void use()
{
    A a;
    a.weeks = 3;
    a.weeks++;
    a.weeks -=2;
    typeof(a.weeks) b = a.weeks;
}
</syntaxhighlight>


Now consider how to implement the above if properties were completely removed, as proposed. The D1 solution allowed assignment syntax for normal functions. So the above example could work exactly the same way, but <code>@property</code> wouldn't be used. This is a poor solution for properties as it allows to write nonsensical code:

<syntaxhighlight lang="D">
void use()
{
    writeln = 42; //would call writeln(42);
    writeln += 1; //How would this even be implemented without @property?
}
</syntaxhighlight>

Note that this is in '''no way related''' to the optional parentheses discussion: You can have parentheses, a @property implementation and still disallow code like <code>writeln = 42;</code>

==== Breakage when removing @property ====
<syntaxhighlight lang="D">
//In druntime's object_.d AssociativeArray has:
@property size_t length() { return _aaLen(p); } //that can't be rewritten as a field, so without @property it must be a function

//Right now:
assert(is(typeof([int][int].length) == size_t);
//Without @property
assert(is(typeof([int][int].length) == size_t function());
</syntaxhighlight>

=== Cons ===
(Please do not add implementation issues, only conceptual issues)

* Some people find it difficult to decide if something is a property or a function
* Some people think the additional <code>@property</code> attribute clutters the source code

=== Property declaration syntax ===
Some new syntaxes have been proposed for property declaration:

* Could make declaring properties less verbose
* Would break lots of code
** Could be done without breakage with new attributes (<code>@prop</code>), but that's ugly
* There's no need for a new syntax. Although the current syntax is verbose, it does not have real issues. The issues happen when using properties, not when declaring them.
** The allowed function prototypes (ref) should be reviewed though and it should be made clear how they interact:


<syntaxhighlight lang="D">
@property ref int prop();
@property int prop();
@property void prop(int value);
@property int prop(int value);
@property void prop(ref int value); //not as problematic
</syntaxhighlight>

=== Implementation concerns ===
* Can we get a reference to the property? What does <code>&x.property_</code> mean?
* How can we get the getter / setter functions? Do we need to get those?
* What is the type of the property? Return type, setter function type or getter function type? How to get the other types?
* What does <code>x.property_++</code> do? ([http://www.prowiki.org/wiki4d/wiki.cgi?DocComments/Property#Semanticrewritingofproperties Semantic rewriting])
* Is returning ref values from the getter OK?
* Is taking ref values in the setter OK?
* Should all properties be nothrow? pure? getter const?
** Probably better as a rule for style guide.
* Are UFCS properties possible? How do they work exactly?
* How do you disambiguate property functions when they're free functions which conflict?
** Normal UFCS functions can be force called by using their fully qualified name. That's not possible for properties if function call syntax is disallowed?
* How many parameters are allowed for property functions?
** Are default parameters allowed?
** Especially consider the example about __FILE__ and __LINE__
* Are templated properties allowed?
** The access syntax for properties doesn't allow providing types

==== Code examples ====
===== __LINE__ / __FILE__ =====
<syntaxhighlight lang="D">
//Currently valid and existing code
public @property string userId(string file = __FILE__, size_t 
line = __LINE__)
{
    if(true)
        throw Exception("", file, line);
}
</syntaxhighlight>

=== Proposals ===
[[Property Discussion Proposal 1]]

== Optional parentheses ==

=== Pro ===
* UFCS code looks nicer:
<syntaxhighlight lang="D">
auto yesterday = 2.days.ago;

some!(e1).ufcs!(e2).chaining!(e3)
//instead of
some!(e1)().ufcs!(e2)().chaining!(e3)()

//We need a real world UFCS case demonstrating this.
//There are real world examples - even in that discussion thread - but I cant find them ;-)
</syntaxhighlight>

=== Extra note ===
The same way "." can dereference pointer, it is unambiguous to automatically call functions on ".". This shortcut is unambiguous (even if some people may find it confusing when reading code).

<syntaxhighlight lang="D">
// Only the last () is necessary in that case.
some!(e1).ufcs!(e2).chaining!(e3)()
</syntaxhighlight>

=== Cons ===
* Ambiguous / complicated if a function returns a delegate or similar (solvable with special case rules)
* Complicates semantics for human reader of the code (see comments about readability in "How those are (not!) related")

=== How those are (not!) related to properties ===
Both properties and optional parentheses are basically orthogonal. It's possible to have both, have none, and have any mix of those.

The small issue where they interfere is code readability:

If optional parentheses are disallowed, it's easy to see that
<syntaxhighlight lang="D">
auto var = new someClass();
auto x = var.something;
</syntaxhighlight>

will always be either a field access or a property call. But according to property definition (as used by C# and other languages), properties should behave like fields (i.e. constant complexity, no side-effects,...). Therefore without optional parentheses it's possible to see if an access is actually a potentially heavy weight function call or data / property access.

Except from this, @property and optional parentheses are orthogonal.

== Unified test suite ==
Aims to provide one source file that provides all use cases that work with current lax rules. Any proposal should give clear answer, which of them are allowed and how those should work.
<syntaxhighlight lang="D">
alias Deleg = int delegate();

struct Test
{
   int var;
	
   @property void native(int param = 1337) { }
   @property int native() { return 42; }
        
   @property int both1(int a) { return a; }

   @property ref int both2() { return var; }
	
   @property void strange() { }
	
   @property Deleg delegRet() { return () => 42; }

   struct Inner
   {
       void func1() { }
       void func2() const { }

       int a;
   }

   Inner inner;

   @property Inner nested1() { return inner }
   @property ref Inner nested2() { return inner }
   @property ref const(Inner) nested3() { return inner }
}
 
@property void external1(int) { } 
@property int external1() { return 42; }

@property void external2(Test, int) { }
@property int external2(Test) { return 42; }

// @property void lotof(Test, int, int, int) { } // Error now

struct Dispatcher1
{
    void opDispatch(string arg)() { }
}
 
struct Dispatcher2
{
    @property void opDispatch(string arg)() { }
}

void main()
{
    Test t;
    t.native = 42;
    t.native;
    t.native(42);
    int a = t.native;
    // t.native++; // Error now
    // t.native += 42; // Error now
    t.strange;
    t.both1 = 42;
    // a = t.both1; // Error now
    t.both2 = 42;
    a = t.both2;
	
    external1 = 42;
    external1(42);
    int b = external1;	
    42.external1;
	
    t.external2 = 42;
    auto c = t.external2;
    external2(t).external1;
	
    t.nested1.func1();
    t.nested1.func2();
    t.nested1.a;
    t.nested2.func1();
    t.nested2.func2();
    t.nested2.a;
    t.nested3.func1();
    t.nested3.func2();
    t.nested3.a;

    t.delegRet;
    t.delegRet();
    t.delegRet()();
	
    pragma(msg, is(typeof(t.var) == typeof(t.native)));
	
    pragma(msg, typeof(external1));
    import std.traits;
    // pragma(msg, typeof(ReturnType!(typeof(external1)))); // Error now
	
    pragma(msg, typeof(&(t.delegRet)));
    pragma(msg, typeof(t.delegRet));
    pragma(msg, typeof(t.delegRet()));
    pragma(msg, typeof(t.delegRet()()));
	
    pragma(msg, ReturnType!(typeof(t.delegRet)));

    Dispatcher1 disp1; Dispatcher2 disp2;
    disp1.something;
    disp1.something();
    disp2.something;
    disp2.something();
}
</syntaxhighlight>